#!/usr/local/cpanel/3rdparty/bin/perl
# cpanel - scripts/updatecgiemail                 Copyright(c) 2014 cPanel, Inc.
#                                                           All rights Reserved.
# copyright@cpanel.net                                         http://cpanel.net
# This code is subject to the cPanel license. Unauthorized copying is prohibited

use strict;

use Cpanel::AccessIds               ();
use Cpanel::Config::LoadUserDomains ();
use Cpanel::FileUtils::Copy         ();
use Cpanel::PwCache                 ();

my @cgifiles = (
    {
        source => '/usr/local/cpanel/cgi-sys/cgiemail',
        dest   => 'public_html/cgi-bin/cgiemail',
    },
    {
        source => '/usr/local/cpanel/cgi-sys/cgiecho',
        dest   => 'public_html/cgi-bin/cgiecho',
    },
);

my %cpusers = Cpanel::Config::LoadUserDomains::loadtrueuserdomains( -1, 1 );

for my $user ( keys %cpusers ) {
    my $homedir = Cpanel::PwCache::gethomedir($user) or next;

    for my $cgifile (@cgifiles) {
        my $realfile = $homedir . '/' . $cgifile->{dest};
        if ( -e $realfile ) {
            my $original_perms = ( stat(_) )[2] & 0777;

            print "File '$realfile' exists.\n";
            print "Replacing with '" . $cgifile->{source} . "'.\n";

            Cpanel::AccessIds::do_as_user(
                $user,
                sub {
                    Cpanel::FileUtils::Copy::safecopy( $cgifile->{source}, $realfile );
                    chmod $original_perms, $realfile;
                }
            );
        }
    }
}